#####################################################################
# Module : Fai.hsm
# Description : Fonctions de connexion aux FAIs
# Auteur : Olivier Zolli <ozolli@online.fr>
# Version : 03/02/01
#####################################################################

#!initialize
  debug(255,"<<< module 'Fai.hsm' >>>")
Return(0)


#####################################################################
# TestCx : Teste si déja connecté à un FAI
# [Entrée] : Aucune
# [Sortie] : $CxHamster
#####################################################################

sub TestCx

VarSet($CxHamster,True)

if(RasIsConnected)
  $CxHamster=False
  print("Déja connecté à "+RasGetConnection)
endif

return($CxHamster)

endsub

#####################################################################
# CxFai : Tente de se connecter à un FAI
# [Entrée] : $FAI : Nom du FAI (connexion à distance valide)
#            $NbEssais : Nombre de tentatives de connexion
#            $Pause : Délai entre 2 tentatives en millisecondes
# [Sortie] : $Connect
#####################################################################

sub Cxfai($Fai,$NbEssais,$Pause)

var($Connect)
varset($try,0)

if(!RasIsConnected)
  repeat
    print("connexion à "+$Fai)
    $Connect=hamrasdial($Fai)
    break($Connect=-1)
    inc($try)
    break($try>=$NbEssais)
    sleep($Pause)
  until(RasIsConnected)
  if($Connect=623)
    $Re=MsgBox($Fai+" : Ce FAI n'est pas valide",_
                 "Hamster-Fr",0x10|0x0)
  endif
endif

return($Connect)

endsub

#####################################################################
# CxMulti : Tente de se connecter à un FAI en suivant une
#           liste de priorités (dans Fai.ini)
# [Entrée] : Aucune
# [Sortie] : Aucune
#####################################################################

sub CxMulti

var($NomFai)
varset($I,0)

do
  inc($I)
  $NomFai=iniread(Hampath+"Fai.ini","FAI","FAI"+$I,0)
  break($NomFai=0)
  Cxfai($NomFai,1,5000)
  break(RasIsConnected)
loop

endsub

#####################################################################
# CxListe : Tente de se connecter à un FAI choisi dans une
#                 boite de dialogue
# [Entrée] : Aucune
# [Sortie] : Aucune
#####################################################################

sub CxListe
   
var($ListeFai,$Boite)

$ListeFai = ListAlloc

if(ListRasEntries($ListeFai)>0)
  $Boite=ListBox($ListeFai,"Choix du FAI","Hamster-Fr",-1)
  if($Boite>=0)
    cxfai(ListGet($ListeFai,$Boite),1,5000)
   endif
endif

ListFree($ListeFai)

endsub