#####################################################################
# Module : Mail.hsm
# Description : Fonctions de traitement du courrier
# Auteur : Olivier Zolli <ozolli@online.fr>
# Version : 03/02/01
#####################################################################

#!initialize
  debug( 255, "<<< module 'Mail.hsm' >>>" )
Return(0)

#####################################################################
# EnvoieCourrier : Envoie le courrier en instance avec le serveur
#                  SMTP du FAI connecté. Le choix se fait grâce à la
#                  section [SMTP] de Fai.ini
# [Entrée] : Aucune
# [Sortie] : Aucune
#####################################################################

sub EnvoieCourrier
 
var($Fai,$NomFai,$Serveur,$Port)
varset($I,0)

do
  inc($I)
  $Fai=iniread(Hampath+"Fai.ini","SMTP","SMTP"+$I,0)
  break($Fai=0)
  RE_Split($Fai,", *",$NomFai,$Serveur,$Port)
  if(RasGetConnection=$NomFai)
    HamSendMail($Serveur,$Port)
    break
  endif
loop

endsub

#####################################################################
# RecoitCourrier : Reçoit le courrier de tous les serveurs présents
#                  Dans Fai.ini section [POP]
# [Entrée] : Aucune
# [Sortie] : Aucune
#####################################################################

sub RecoitCourrier

var($Pop,$Serveur,$Port,$Util,$Pass,$compte,$Filtre)
varset($I,0)

do
  inc($I)
  $Pop=iniread(Hampath+"Fai.ini","POP","POP"+$I,0)
  break($Pop=0)
  RE_Split($Pop,", *",$Serveur,$Port,$Util,$Pass,$compte,$Filtre)
  HamFetchMail($Serveur,$Port,$Util,$Pass,$compte,$Filtre)
loop

endsub